Activate your main form, and hit ALT+F11 to display the "Use Unit" dialog. Add the "ROFuncs" file to your uses and click the "OK" button.

Now, alter the event handlers for your buttons as shown below (new code is in blue):

procedure TForm2.Button1Click(Sender: TObject);
var
  ROMsg: TROMessage;
begin
  ROWinInetHTTPChannel1.TargetURL := Edit1.Text;
  ROMsg := GetMessage(Edit1.Text);
  try
    with CoSmartService.Create(ROMsg, ROWinInetHTTPChannel1) do
       ShowMessage(IntToStr(Sum(1, 2)));
  finally
    ROMsg.Free;
  end;
end ;

procedure TForm2.Button2Click(Sender: TObject);
var
  ROMsg: TROMessage;
begin
  ROWinInetHTTPChannel1.TargetURL := Edit1.Text;
  ROMsg := GetMessage(Edit1.Text);
  try
    with CoSmartService.Create(ROMsg, ROWinInetHTTPChannel1) do
      ShowMessage(DateTimeToStr(GetServerTime));
  finally
    ROMsg.Free;
  end;
end ;

Compile and run your application. Now, for your service location, you can either indicate a trailing "/ SOAP" to access your Smart Service via the SOAP protocol, or "/BIN" to access it via the BIN message protocol. RemObjects seamlessly takes care of the rest.

Scaling back your Smart Service™

Having a central service for business logic is essential in today's business world. However, the technical market is far from shunning the need to have a local application. While more and more people are equipped with Internet connections, many clients still require a local solution. RemObjects Smart Services can fill this gap too, with only a few lines of code. This means that you can use the exact same code base for your ISAPI Smart Service, your local dynamic link library Smart Service, and your standards-compliant SOAP Web Service. They are all the same file!

RemObjects has a built in wizard for creating a local link library service as easily as our ISAPI service. However, because we want to adapt our existing ISAPI service to function as a local service as well, we need to add a few lines of code to our SmartProject. In the Delphi "Project Manager", activate your SmartProject service. Right click on the "SmartProject.dll" project node, and click the "View Source" menu item. Add uRODLLServer, uROBINMessage and Windows to your project's uses clause. Add the following code (new code is in blue):

var BINMessage : TROBINMessage;

procedure ROProc(Reason:integer);
begin
  case Reason of
    DLL_PROCESS_ATTACH: begin
      BINMessage := TROBINMessage.Create( NIL );
      RegisterMessage(BINMessage);
    end ;
    DLL_PROCESS_DETACH: begin
      BINMessage.Free;
    end ;
  end ;
end ;

exports
  GetExtensionVersion,
  HttpExtensionProc,
  TerminateExtension;

begin               
  DLLProc:=@ROProc;
  ROProc(DLL_PROCESS_ATTACH);
  CoInitFlags := COINIT_MULTITHREADED;
  Application.Initialize;
  Application.CreateForm(TMainModule, MainModule);
  Application.Run;
end .

Recompile your service. Your service is now ready to serve either via HTTP or as a local dynamic link library. Let's expand on our client application and try it out!

Consuming a local Smart Service™ Library

In the Delphi “Project Manager”, activate your client application project. Open the RUFuncs.pas file in the Delphi editor. Add uROWinInetHTTPChannel and uRODLLChannel to the ROFuncs uses clause.   Add the following GetChannel() function and alter the existing GetMessage() function as seen below (new code is in blue):

function GetChannel(Location: string ): TROTransportChannel;

function GetMessage(Location: string ): TROMessage;

implementation

uses uROWinInetHTTPChannel, uRODLLChannel, SysUtils, uROBINMessage, uROSOAPMessage, Classes ;

function GetChannel(Location: string ): TROTransportChannel;
begin
  if (FileExists(Location)) and (UpperCase(ExtractFileExt(Location)) = '.DLL') then
  begin
    Result := TRODLLChannel.Create( nil );
    TRODLLChannel(Result).DLLName := Location;
  end else
  begin
    Result := TROWinInetHTTPChannel.Create( nil );
    TROWinInetHTTPChannel(Result).TargetURL := Location;
  end ;
end ;  

function GetMessage(Location: string ): TROMessage;
begin
  if (FileExists(Location)) and (UpperCase(ExtractFileExt(Location)) = '.DLL') then
  begin
    Result := TROBINMessage.Create( nil );
    TROBINMessage(Result).UseCompression := True;
  end else
  begin
    if (Length(Location) > 3) and
      (UpperCase(Copy(Location, Length(Location) - 3, 4)) = '/BIN') then
    begin
      Result := TROBINMessage.Create( nil );
      TROBINMessage(Result).UseCompression := True;
    end else
    begin
      Result := TROSOAPMessage.Create(TComponent( nil ));
    end;
  end;
end;

Now we have a function that will return an RO Channel object depending on the "Location" parameter, and we have adapted our GetMessage() function to check to see if a local library file is passed as the "Location" parameter. Activate your main form and remove the WinInet Channel component. Alter your event handlers as follows (new code is in blue):

procedure TForm2.Button1Click(Sender: TObject);
var
  ROMsg: TROMessage;
  ROChannel: TROTransportChannel;
begin
  ROMsg := GetMessage(Edit1.Text);
  ROChannel := GetChannel(Edit1.Text);
  try
    with CoSmartService.Create(ROMsg, ROChannel) do
      ShowMessage(IntToStr(Sum(1, 2)));
  finally
    ROMsg.Free;
    ROChannel.Free;
  end;
end;

procedure TForm2.Button2Click(Sender: TObject);
var
  ROMsg: TROMessage;
  ROChannel: TROTransportChannel;
begin         
  ROMsg := GetMessage(Edit1.Text);
  ROChannel := GetChannel(Edit1.Text);
  try
    with CoSmartService.Create(ROMsg, ROChannel) do
      ShowMessage(DateTimeToStr(GetServerTime));
  finally
    ROMsg.Free;
    ROChannel.Free;
  end;
end;

We have simply altered our even handlers to use our new GetChannel() method to retrieve an appropriate RO Channel object for our given location. Run the program and try it!

Consuming your Smart Service™ in Microsoft C#

After the Visual Studio IDE is loaded,click "File|New|Blank Solution". Select the "Visual C# Projects" folder and the "ASP. NET Web Application" item. Fill out the dialog as show below:

Click the "OK" button. Design a form similar to the one below, with a TextBox, two Buttons, and an output Label.

Right click on the "References" folder in the "Solution Explorer" window and click "Add Web Reference". Fill in the SOAP URL for your Smart Service and click the "Go" button.

Click the "Add Reference" button. Add the following event handlers to your two Buttons:

private void Button1_Click( object sender, System.EventArgs e)
 {
       localhost.SmartServiceService SmartSrvc;
       SmartSrvc = new localhost.SmartServiceService();
       ResultLabel.Text = "1 + 2 = " + SmartSrvc.Sum(1, 2).ToString();
 }
private void Button2_Click( object sender, System.EventArgs e)
 {
       localhost.SmartServiceService SmartSrvc;
       DateTime ServTime ;
       SmartSrvc = new localhost.SmartServiceService();
       ServTime = SmartSrvc.GetServerTime();
       ResultLabel.Text = ServTime.ToString();
 }